Negative p3 values dont exitst, real legato isnt on surface

Newbies
#1

I’ve reed manual and its really weird… Negative p3 value events must end with some events to work. The purpose of negative p3 values other than weird itie usage is unknown, and all of that is from official manual! Can i please get a working glide from previous freq to next freq without 3 events with 3 different instruments, i know next event dont override that exact instrument, its a lie, can i change freq via score without pain?

#2

this is a simple example:

instr 1
aSine = poscil:a(.2,random:i(400,500),-1,-1)
outall(aSine)
endin

and in the score:
i 1 0 -1
i 1 1 -1
i 1 2 -1
i 1 3 -1

where did you find the description in the manual?
please suggest an improvement, if possible via a github ticket on

long time ago, steven yi wrote an article about tied notes in csound:
https://csoundjournal.com/2005fall/tiedNotes.html

best -
joachim

1 Like
#3

Thanks a lot. Will try

#4

ok this paper is GOLD. wouldn’t ever find it myself, can only wonder why it isn’t in manual. Its crucial for legato. Didn’t even know it works how it needs to work and this clicks could be by skipping initialisation. second day in csound glad there is people on forum

;
; "Tied Note Example"
; by Steven Yi
;
; Example instruments and score written for "Exploring Tied Notes in Csound" article in The Csound Journal, Volume 1, Issue 1.
;
; Generated by blue 0.99.7 (http://csounds.com/stevenyi/blue/index.html)
;

<CsoundSynthesizer>

<CsInstruments>
sr=44100
ksmps=10
nchnls=2
0dbfs=1





	opcode tieStatus,i,0

itie tival

if (itie == 0 && p3 < 0) ithen
    ; this is an initial note within a group of tied notes
    itiestatus = 0
       
elseif (p3 < 0 && itie == 1) ithen
    ; this is a middle note within a group of tied notes 
    itiestatus = 1

elseif (p3 > 0 && itie == 1) ithen
    ; this is an end note out of a group of tied notes
    itiestatus = 2

elseif (p3 > 0 && itie == 0) ithen
    ; this note is a standalone note
    itiestatus = -1

endif  

	xout	itiestatus

	endop


	instr 1	;Normal Instrument
	idur = abs(p3)
	ipch	= cpspch(p4)
	iskip tival
	itie1 tieStatus
 tigoto skipInit
 ioldpch init ipch
skipInit:

inewpch 	= ipch
kpchline	linseg	ioldpch, .2, inewpch, idur - .05,  inewpch
ioldpch	= inewpch

if (itie1 == -1) then
    kenv	adsr	.05, .05, .9, .05

elseif (itie1 == 0) then	
    kenv	linseg	0, .05, 1,  .2, 1

elseif (itie1 == 1) then	
    kenv init 1

elseif (itie1 == 2) then
    kenv linseg	1, idur - .05, 1, .05, 0 
    endif
    itab = ftgen(1, 0 ,2048, 10 , 1)

	asig oscil 1, kpchline,itab,p3
	asig = asig*kenv
	 outs asig, asig
	endin
	
</CsInstruments>

<CsScore>
i1 0 -1 8.04
i1 +  -1 9.04 
i1 + . 7.04
i1 + -1  .
</CsScore>

</CsoundSynthesizer>

cool

#5

The journal can be found from the ‘Learn’ tab on the Csound homepage. But I wonder if clicking that link should take one straight to the list of articles by title instead of issues, which doesn’t give much away in terms of content? @joachim what do you think?

#6

yeah good idea — will do!

#7

good to know it was useful for you.

you ask why it is not in the manual. my answer would be: because we
need to contribute to the manual if we find lacks or mistakes.

if you reply to my previous question where you found the description
about negative p3 or legato or tied notes in the manual (as i don’t
know), we can add an issue at Issues · csound/manual · GitHub or
propose a pull request.